//
// Plots Cumulative Delta
//
// Start at the begining of day and plot as a 'bar'
// Has large trade and small trade filter
// 
// By BlowFish / NickA

inputs: 
	UpColor(darkgreen), 
	DownColor(red), 
	MaxBlock(9999),
	MinBlock(0),
	ResetDeltaEachBar(0); 
	 	 
variables: 
	MyVol(0), 
	Block(0),
	color(yellow), 
	firstrunthrough(true),
	intrabarpersist MyCurrentBar(0), 
	intrabarpersist VolTmp(0), 
	intrabarpersist Delta (0), 
	intrabarpersist DeltaH (0), 
	intrabarpersist DeltaL (0), 
	intrabarpersist DeltaO (0); 
	
if firstrunthrough then begin				// We need to do this in case indicator starts mid bar
   	Voltmp = Iff(BarType < 2, Ticks, Volume);
   	firstrunthrough = False;
   	end;
 
if LastBarOnChart then begin    	
	if CurrentBar > MyCurrentBar then begin 
		VolTmp = 0; 
		MyCurrentBar = CurrentBar; 
		if ResetDeltaEachbar = 1 then Delta =0;
		DeltaO = Delta; 
		DeltaH = Delta; 
		DeltaL = Delta; 
	end; 
   	MyVol = Iff(BarType < 2, Ticks, Volume);
	Block = Myvol - VolTmp;
	if (Block >= MinBlock) and (Block <= MaxBlock) then
		if Close <= InsideBid then
			Delta  = Delta - MyVol + VolTmp
		else if Close >= InsideAsk then 
			Delta = Delta + MyVol - VolTmp ;  
		VolTmp = MyVol ;


 
DeltaH = maxlist(DeltaH, Delta); 
DeltaL = minlist(DeltaL, Delta); 
 
 
 if Delta <= Delta[1] then color = DownColor else color = UpColor; 
 
	plot1(DeltaO, "DO",color); 
	Plot2(DeltaH, "DH",color); 
	Plot3(DeltaL, "DL",color); 
	plot4(Delta, "DC",color);	 
end;